breed [ users user ]
breed [ computers computer ]

globals [
  hidden-strategy
]

turtles-own [
  score                  ; my current score
  defect-now?            ; what will I do this round?
  partner                ; my partner
  partner-defected?      ; did my partner defect last round?
  partner-defected-past? ; did my partner defect two rounds ago?
]

to setup
  clear-all
  ; place the computer
  set-default-shape computers "computer"
  create-computers 1 [
    set heading 90
    fd max-pxcor / 2
  ]
  ; place the human
  set-default-shape users "person"
  create-users 1 [
    set heading 270
    fd abs min-pxcor / 2
  ]
  ask turtles [
    set size 10
    set partner one-of other turtles
    ; initially assume you and your partner have always cooperated
    set defect-now? false
    set partner-defected? false
    set partner-defected-past? false
    set score 3.0
  ]
  ; choose the secret strategy the computer will
  ; play if select-computer-strategy? is off
  set hidden-strategy one-of [
    "act-randomly" "cooperate" "defect" "tit-for-tat"
    "tit-for-two-tats" "unforgiving" "custom-strategy"
  ]
  reset-ticks
  prepare-next-round
end

;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Runtime Procedures;;;
;;;;;;;;;;;;;;;;;;;;;;;;;

to play
  play-a-round
  tick
  prepare-next-round
end

to play-a-round
  ; run the strategy selected by the human
  ask users [ run human-strategy ]
  ; run the strategy selected for the computer, or the
  ; hidden strategy if `select-computer-strategy?` is off
  ifelse select-computer-strategy?
    [ ask computers [ run computer-strategy ] ]
    [ ask computers [ run hidden-strategy ] ]
  ; determine this round's payoffs based on the action each agent has chosen
  ask turtles [ get-payoff ]
end

to prepare-next-round
  ; update the displayed score in the view
  ask turtles [ set label average-score ]
  ; display the computer's action in the last round
  if display-history? [
    ask users [
      ifelse defect-now?
        [ output-print "Last turn you defected." ]
        [ output-print "Last turn you cooperated." ]
      ifelse partner-defected?
        [ output-print "Last turn your partner defected." ]
        [ output-print "Last turn your partner cooperated." ]
    ]
    output-print "Choose your action!"
  ]
end

to-report average-score ; Turtle reporter
  report precision (score / (ticks + 1)) 3
end

;;;;;;;;;;;;;;;;;;
;;; Strategies ;;;
;;;;;;;;;;;;;;;;;;

to act-randomly ; Turtle Procedure
  set defect-now? one-of [ true false ]
end

to cooperate ; Turtle Procedure
  set defect-now? false
end

to defect ; Turtle Procedure
  set defect-now? true
end

to tit-for-tat ; Turtle Procedure
  ifelse partner-defected?
    [ set defect-now? true ]
    [ set defect-now? false ]
end

to tit-for-two-tats ; Turtle Procedure
  ifelse partner-defected? and partner-defected-past?
    [ set defect-now? true ]
    [ set defect-now? false ]
end

to unforgiving ; Turtle Procedure
  ifelse partner-defected? or defect-now?
    [ set defect-now? true ]
    [ set defect-now? false ]
end

to custom-strategy ; Turtle Procedure
  ; Currently defaults to tit-for-tat.  Can you do better?
  ifelse partner-defected? ; partner defected stores your partner's action last round
    [ set defect-now? true ]
    [ set defect-now? false ]
end

;;;;;;;;;;;;;;;;;;;;;;
;;; End Strategies ;;;
;;;;;;;;;;;;;;;;;;;;;;

to get-payoff ; Turtle Procedure
  set partner-defected-past? partner-defected?
  set partner-defected? [ defect-now? ] of partner
  ifelse partner-defected?
    [ ifelse defect-now?
      [ set score score + 1 ]
      [ set score score + 0 ]
    ]
    [ ifelse defect-now?
      [ set score score + 5 ]
      [ set score score + 3 ]
    ]
end


; Copyright 2002 Uri Wilensky.
; See Info tab for full copyright and license.
@#$#@#$#@
GRAPHICS-WINDOW
329
10
722
206
-1
-1
11.0
1
24
1
1
1
0
0
0
1
-17
17
-8
8
1
1
1
ticks
30.0

BUTTON
6
23
87
56
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
22
200
112
245
human score
[ score ] of one-of users
3
1
11

MONITOR
115
200
220
245
computer score
[ score ] of one-of computers
3
1
11

PLOT
22
249
305
418
Average Score
Iterations
Ave Score
0.0
10.0
0.0
5.0
true
true
"" ""
PENS
"human" 1.0 0 -16777216 true "" "plot [ average-score ] of one-of users"
"computer" 1.0 0 -13345367 true "" "plot [ average-score ] of one-of computers"

BUTTON
87
23
183
56
Play Once
play
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
0

BUTTON
183
23
313
56
Play Repeatedly
play
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
0

SWITCH
59
108
258
141
select-computer-strategy?
select-computer-strategy?
0
1
-1000

SWITCH
330
250
502
283
display-history?
display-history?
0
1
-1000

CHOOSER
59
63
258
108
human-strategy
human-strategy
"act-randomly" "cooperate" "defect" "tit-for-tat" "tit-for-two-tats" "unforgiving" "custom-strategy"
0

CHOOSER
59
141
258
186
computer-strategy
computer-strategy
"act-randomly" "cooperate" "defect" "tit-for-tat" "tit-for-two-tats" "unforgiving" "custom-strategy"
3

OUTPUT
330
284
723
418
12

@#$#@#$#@
## WHAT IS IT?

This model is an iterated version of the prisoner's dilemma.  If you are unfamiliar with the basic concepts of the prisoner's dilemma, please refer to the PD Basic model found in the Prisoner's Dilemma suite.

## HOW IT WORKS

The PD Basic model presents an interesting problem: In order to minimize the overall jail time you would cooperate with your partner and remain silent and not confess.  However, the rational choice is to defect against your partner by confessing.  If your partner does not confess you will go free.  If your partner confesses, you will go to jail for three years, much better than the five you would have earned had you refused to confess.  Unfortunately, your partner is in the same position.  Acting rationally, you will both be worse off.

The dilemma is made more interesting when you know you will interact with the person again.  Let us consider the case where you and a friend are chosen for a research study to play the prisoner's dilemma game; only instead of the payoffs being years of jail time, they are money.

The researchers separate you and your friend into separate rooms allowing communication to occur only through a computer.  They give you a sheet with the rules for the iterated prisoner's dilemma that reads as follows:

1.  This game will consist of an unspecified number of rounds.  At the end of the game, you will receive $1 for each point you have earned.

2.  Each round you and your partner will have the opportunity to earn points by choosing to either cooperate (C) or defect (D).  Communication will be done only through the computer.  The only message you will be able to pass is cooperate or defect.  Neither person will see the other's message until both have chosen their action.

3.  Your payoff for each round will determined by the actions as follows:

<table border>
<tr><th><th colspan=2>partner's action
<tr><th>your action<th>C<th>D
<tr><td>C<td>3<td>0
<tr><td>D<td>5<td>1
</table>

(Note: This way of determining your payoff is the opposite of the PD Basic model. In PD Basic, you were "awarded" something bad --- jail time. In this model, you are awarded something good --- money.)

Your partner has an identical payoff matrix.

To get things started, the model assumes that the user and the computer already played a round where they cooperated with each other, so both players start with a score of 3.

## HOW TO USE IT

Buttons:

SETUP: Begin playing the iterated prisoner's dilemma.  If you choose to turn the SELECT-COMPUTER-STRATEGY? switch off before pressing this button, the computer's strategy will be randomly chosen at this time.

PLAY ONCE: Play a single round of the prisoner's dilemma with the strategy you have selected.

PLAY REPEATEDLY: Repeatedly play rounds of the prisoner's dilemma between you and the computer.  You can change your strategy at any time.  If the SELECT-COMPUTER-STRATEGY? switch is on you can also change the computer's strategy at any time.

With both PLAY buttons, the computer's action each round will be displayed in the command center.

Switches:

SELECT-COMPUTER-STRATEGY?: If on, you may select the computer's strategy using the computer strategy slider.  If off, the computer's strategy will be randomly chosen from the strategy list found below, excluding the Custom Strategy.

DISPLAY-HISTORY?: Turn on or off messaging in the command center.

Sliders:

HUMAN-STRATEGY - Select your strategy from the list below.

COMPUTER STRATEGY - Select the computer's strategy from the list below.

Strategies:

- **Act-Randomly** - randomly cooperate or defect
- **Cooperate** - cooperate always
- **Defect** - defect always
- **Tit-for-Tat** - If the opponent cooperates this round cooperate next round.  If the opponent defects this round, defect next round.  Initially cooperate.
- **Tit-for-Two-Tats** - If the opponent cooperates this round cooperate next round.  If the opponent defects two rounds in a row, defect the next round.  Initially cooperate.
- **Unforgiving** - Cooperate always unless the opponent defects once.  Upon opponent defection retaliate by defecting always.
- **Custom-Strategy** - This strategy is intended to be written by you.  It currently defaults to Tit-for-Tat.

Monitors:

HUMAN SCORE - The total points you have earned

COMPUTER SCORE - The total points the computer has earned

Plots:

AVERAGE SCORE: The average scores of you and the computer each round vs. the number of iterations.  This is a good indicator of how well you are doing relative to the maximum possible average of $5 per round.

## THINGS TO NOTICE

Should the computer always play the "Cooperate" strategy, then which strategy for the user results in the highest score?

If the computer always plays "Defect", then what is the nature of the average score plot when the user plays "Tit-for-Tat", "Tit-for-Two-Tat", "Unforgiving", and "Custom Strategy"?  Why does such a nature arise for these combination of strategies?

What is the nature of the plot for average score when the computer always plays "Tit-for-Tat" and the user plays every strategy except "Defect" and "Act-Randomly"?  Why does such a curve arise?

## THINGS TO TRY

1. Turn the SELECT-COMPUTER-STRATEGY? switch off.  Setup the model and play the iterated prisoner's dilemma against the computer.  You may choose between selecting your strategy each round using the PLAY ONCE button, or automating your choices each round using the PLAY REPEATEDLY button.  What approach wins you the most money?

2. Turn the SELECT-COMPUTER-STRATEGY? switch on.  Experiment with playing different strategies against one another.  Which strategies do the best?  Which do the worst?  Why?

3. Repeat task 1 several times.  How does the best strategy vary?  Based on you experience in task 2, why might this be so?

4. The researchers now tell you that they will double the amount of money the person with the most points gets at the end, but the other person will get nothing.  In the event of a tie, each person still receives $1 per point.  How does this change your strategy?  Why?

5. Describe a real life scenario that is similar to the iterated prisoner's dilemma, preferably one you have experienced.  How might the strategies examined here relate to actions taken in that scenario?

## EXTENDING THE MODEL

Even the most complex strategies in this model are relatively simple.  Surely you can do better.  Redefine the CUSTOM-STRATEGY procedure attempting to develop a strategy that can earn a higher score than those presented in the model or a human player.  Test it against the other strategies and yourself.  What are its strengths?  What are its weaknesses?  Try to keep improving it.

Examine the PD N-PERSON ITERATED model

## NETLOGO FEATURES

The model uses the turtle variable [`label`](http://ccl.northwestern.edu/netlogo/docs/dictionary.html#label) to display each turtle's average score in the view.

The model uses the [`run`](http://ccl.northwestern.edu/netlogo/docs/dictionary.html#run) primitive to execute the procedure whose name corresponds to the chosen strategy.

## RELATED MODELS

PD Basic, PD N-Person Iterated, PD Basic Evolutionary

## HOW TO CITE

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

* Wilensky, U. (2002).  NetLogo PD Two Person Iterated model.  http://ccl.northwestern.edu/netlogo/models/PDTwoPersonIterated.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

Please cite the NetLogo software as:

* Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

## COPYRIGHT AND LICENSE

Copyright 2002 Uri Wilensky.

![CC BY-NC-SA 3.0](http://ccl.northwestern.edu/images/creativecommons/byncsa.png)

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License.  To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227.

<!-- 2002 -->
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

computer
false
0
Rectangle -7500403 true true 15 15 285 210
Rectangle -16777216 true false 28 27 270 195
Rectangle -10899396 true false 50 46 255 52
Rectangle -10899396 true false 53 163 250 171
Circle -10899396 true false 166 117 9
Rectangle -10899396 true false 153 70 205 76
Rectangle -10899396 true false 84 145 147 153
Rectangle -7500403 true true 135 210 165 240
Polygon -7500403 true true 30 285 45 240 255 240 270 285 30 285 30 285
Line -16777216 false 45 270 255 270
Line -16777216 false 51 255 246 255
Line -16777216 false 75 270 75 255
Line -16777216 false 90 270 90 255
Line -16777216 false 105 270 105 255
Line -16777216 false 120 270 120 255
Line -16777216 false 135 270 135 255
Line -16777216 false 150 270 150 255
Line -16777216 false 165 270 165 255
Line -16777216 false 180 270 180 255
Line -16777216 false 195 270 195 255
Line -16777216 false 210 270 210 255
Line -16777216 false 225 270 225 255
Line -16777216 false 240 270 240 255
Line -16777216 false 60 270 60 255

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.2.2
@#$#@#$#@
setup
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
1
@#$#@#$#@
