GAP (SLA) - Chapter 3: Semisimple Lie Algebras and their Modules

Goto Chapter: Top 1 2 3 4 5 6 Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax on]

3 Semisimple Lie Algebras and their Modules
3.1 Semisimple Lie algebras
3.1-1 IsomorphismOfSemisimpleLieAlgebras
3.1-2 DisplayDynkinDiagram
3.1-3 ApplyWeylPermToCartanElement
3.2 Representations of semisimple Lie algebras
3.2-1 AdmissibleLattice
3.2-2 DirectSumDecomposition
3.2-3 IsIrreducibleHWModule
3.2-4 HighestWeightVector
3.2-5 HighestWeight
3.2-6 DisplayHighestWeight
3.2-7 IsomorphismOfIrreducibleHWModules
3.2-8 DualAlgebraModule
3.2-9 CharacteristicsOfStrata

### 3 Semisimple Lie Algebras and their Modules

#### 3.1 Semisimple Lie algebras

##### 3.1-1 IsomorphismOfSemisimpleLieAlgebras

`‣ IsomorphismOfSemisimpleLieAlgebras`( L1, L2 ) | ( operation )

Here L1 and L2 are two semisimple Lie algebras that are known to be isomorphic (i.e., they have the same type). This function returns an isomorphism.

##### 3.1-2 DisplayDynkinDiagram

`‣ DisplayDynkinDiagram`( L ) | ( operation )

Here L is a semisimple Lie algebra. This function displays its Dynkin diagram.

    gap> L:= SimpleLieAlgebra("F",4,Rationals);
    <Lie algebra of dimension 52 over Rationals>
    gap> DisplayDynkinDiagram(L);
    F4:  2---4=>=3---1

##### 3.1-3 ApplyWeylPermToCartanElement

`‣ ApplyWeylPermToCartanElement`( L, w, h ) | ( operation )

Here L is a semisimple Lie algebra, w is a permutation which is an element of WeylGroupAsPermGroup( RootSystem(L) ), and h is an element of the Cartan subalgebra CartanSubalgebra( L ). The Weyl groups naturally acts on this Cartan subalgebra and this function returns the result of applying w to h.

    gap> L:= SimpleLieAlgebra("F",4,Rationals);;
    gap> R:= RootSystem(L);;
    gap> W:= WeylGroupAsPermGroup(R);;
    gap> w:= Product( GeneratorsOfGroup(W) );
    (1,32,33,36,35,27,25,8,9,12,11,3)(2,30,34,44,37,39,26,6,10,20,13,15)(4,16,23,24,22,18,28,
    40,47,48,46,42)(5,31,41,43,45,38,29,7,17,19,21,14)
    gap> H:= CartanSubalgebra(L);;
    gap> h:= Sum( Basis(H) );
    v.49+v.50+v.51+v.52
    gap> ApplyWeylPermToCartanElement( L, w, h );
    (-1)*v.52

#### 3.2 Representations of semisimple Lie algebras

##### 3.2-1 AdmissibleLattice

`‣ AdmissibleLattice`( V ) | ( operation )

Here V is a simple module over a semisimple Lie algebra. This function returns a basis of V that spans an admissible lattice in V. This means that for a root vector x of the acting Lie algebra the matrix exp( mx ) is integral, where mx denotes the matrix of x relative to the admissible lattice.

    gap> L:= SimpleLieAlgebra("G",2,Rationals);;
    gap> V:= HighestWeightModule( L, [2,0] );
    <27-dimensional left-module over <Lie algebra of dimension 14 over Rationals>>
    gap> B:=AdmissibleLattice(V);;
    gap> x:= L.1;
    v.1
    gap> mx:= MatrixOfAction( B, x );;
    gap> IsZero(mx^4); IsZero(mx^5);
    false
    true
    gap> exp:=Sum( List( [0..4], i -> mx^i/Factorial(i) ) );;
    gap> ForAll( Flat(exp), IsInt );
    true

##### 3.2-2 DirectSumDecomposition

`‣ DirectSumDecomposition`( V ) | ( operation )

Here V is a module over a semisimple Lie algebra; this function computes a list of sub-modules such that V is their direct sum.

    gap> L:= SimpleLieAlgebra("G",2,Rationals);;
    gap> V:= HighestWeightModule( L, [1,0] );;
    gap> W:= TensorProductOfAlgebraModules( V, V );
    <49-dimensional left-module over <Lie algebra of dimension 14 over Rationals>>
    gap> DirectSumDecomposition( W );
    [ <left-module over <Lie algebra of dimension 14 over Rationals>>,
      <left-module over <Lie algebra of dimension 14 over Rationals>>,
      <left-module over <Lie algebra of dimension 14 over Rationals>>,
      <left-module over <Lie algebra of dimension 14 over Rationals>> ]
    gap> List( last, Dimension );
    [ 27, 7, 14, 1 ]

##### 3.2-3 IsIrreducibleHWModule

`‣ IsIrreducibleHWModule`( V ) | ( operation )

Returns true if V is an irreducible module over a semisimple Lie algebra, and false otherwise

    gap> L:= SimpleLieAlgebra("F",4,Rationals);
    <Lie algebra of dimension 52 over Rationals>
    gap> V:= HighestWeightModule( L, [0,1,0,0] );
    <52-dimensional left-module over <Lie algebra of dimension 52 over Rationals>>
    gap> IsIrreducibleHWModule(V);
    true

##### 3.2-4 HighestWeightVector

`‣ HighestWeightVector`( V ) | ( operation )

Here V is an irreducible module over a semisimple Lie algebra. This function returns a highest weight vector v0 in V. This means that it is a weight vector for the Cartan subalgebra of the acting Lie algebra, and all positive root vectors send it to zero.

    gap> L:= SimpleLieAlgebra("G",2,Rationals);;
    gap> V:= HighestWeightModule( L, [1,0] );;
    gap> W:= TensorProductOfAlgebraModules( V, V );;
    gap> dW:= DirectSumDecomposition( W );;
    gap> cg:= CanonicalGenerators( RootSystem(L) );;
    gap> v0:= HighestWeightVector( dW[3] );
    1*(1*v0<x>y1*v0)-1*(y1*v0<x>1*v0)
    gap> List( cg[3], h -> h^v0 );
    [ <0-tensor>, 1*(1*v0<x>y1*v0)-1*(y1*v0<x>1*v0) ]
    gap> List( cg[1], h -> h^v0 );
    [ <0-tensor>, <0-tensor> ]

##### 3.2-5 HighestWeight

`‣ HighestWeight`( V ) | ( operation )

Here V is an irreducible module over a semisimple Lie algebra. This function returns the highest weight of V. That is, the list of eigenvalues of the Cartan elements in a canonical generating set of the Lie algebra, when acting on a highest weight vector.

    gap> L:= SimpleLieAlgebra("G",2,Rationals);;
    gap> V:= HighestWeightModule( L, [1,0] );;
    gap> W:= TensorProductOfAlgebraModules( V, V );;
    gap> dW:= DirectSumDecomposition( W );;
    gap> List( dW, HighestWeight );
    [ [ 2, 0 ], [ 1, 0 ], [ 0, 1 ], [ 0, 0 ] ]

##### 3.2-6 DisplayHighestWeight

`‣ DisplayHighestWeight`( V ) | ( operation )

Here V is an irreducible module over a semisimple Lie algebra. This function displays its highest weight, that is, it shows the coordinates of the highest weight on the Dynkin diagram of the Lie algebra.

    gap> r:= LieAlgebraAndSubalgebras( "E8" );;
    gap> L:= r.liealg;;
    gap> K:= r.subalgs[823];
    <Lie algebra of dimension 58 over CF(84)>
    gap> DisplayDynkinDiagram(K);
    A1:  1
    B5:  2---3---4---5=>=6
    gap> V:= AdjointModule( L );
    <248-dimensional left-module over <Lie algebra of dimension 248 over CF(84)>>
    gap> W:= ModuleByRestriction( V, K );
    <248-dimensional left-module over <Lie algebra of dimension 58 over CF(84)>>
    gap> dW:= DirectSumDecomposition( W );
    [ <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>>,
      <left-module over <Lie algebra of dimension 58 over CF(84)>> ]
    gap> List( dW, Dimension );
    [ 33, 3, 3, 3, 64, 64, 11, 11, 55, 1 ]
    gap> DisplayHighestWeight( dW[5] );
    A1:  1
    B5:  0---0---0---0=>=1
    gap> DisplayHighestWeight( dW[1] );
    A1:  2
    B5:  1---0---0---0=>=0

##### 3.2-7 IsomorphismOfIrreducibleHWModules

`‣ IsomorphismOfIrreducibleHWModules`( V1, V2 ) | ( operation )

Here V1, V2 are two irreducible modules over the same semisimple Lie algebra with the same highest weights. This function returns an isomorphism between the two.

    gap> r:= LieAlgebraAndSubalgebras( "E8" );;
    gap> L:= r.liealg;;
    gap> K:= r.subalgs[823];;
    gap> DisplayDynkinDiagram(K);
    A1:  1
    B5:  2---3---4---5=>=6
    gap> V:= AdjointModule( L );;
    gap> W:= ModuleByRestriction( V, K );;
    gap> dW:= DirectSumDecomposition( W );;
    gap> DisplayHighestWeight( dW[5] );
    A1:  1
    B5:  0---0---0---0=>=1
    gap> DisplayHighestWeight( dW[6] );
    A1:  1
    B5:  0---0---0---0=>=1
    gap> f:= IsomorphismOfIrreducibleHWModules( dW[5], dW[6] );;
    gap> Image( f, HighestWeightVector( dW[5] ) );
    v.205
    gap> HighestWeightVector( dW[6] );
    v.205

##### 3.2-8 DualAlgebraModule

`‣ DualAlgebraModule`( V ) | ( operation )

Here V is a module over a Lie algebra. This function returns the dual module.

The basis elements of this module are printed as F@v where v is a basis element of v. This represents the function which takes the value 1 on te basis element v and 0 on all other basis elements. However, an element of the module is a module element and not a function. We can access the function by taking the ExtRepOfObj of an element of the module, as illustrated by the example below.

    gap> L:= SimpleLieAlgebra("E",6,Rationals);;
    gap> V:= HighestWeightModule( L, [0,0,1,0,0,0] );; Dimension(V);
    351
    gap> Vst:= DualAlgebraModule( V );
    <351-dimensional left-module over <Lie algebra of dimension 78 over Rationals>>
    gap> DisplayHighestWeight( Vst );
                 0
                 |
    E6:  0---0---0---1---0
    gap> DisplayHighestWeight( V );
                 0
                 |
    E6:  0---1---0---0---0
    gap> v0:= HighestWeightVector( Vst );
    (1)*F@y15*y23*y36^(2)*v0
    gap> f:= ExtRepOfObj( v0 );
    (1)*F@y15*y23*y36^(2)*v0
    gap> Image(f, Basis(V)[10] );
    0

##### 3.2-9 CharacteristicsOfStrata

`‣ CharacteristicsOfStrata`( L, hw ) | ( operation )

`‣ CharacteristicsOfStrata`( L, B, hw ) | ( operation )

Here L is a semisimple Lie algebra over a field of characteristic 0. Secondly, hw is a dominant weight, represented as a list of non-negative integers (where the ordering of the fundamantal weights is given by the Cartan matrix of the root system of L). Let G denote the semisimple algebraic group acting on the irreducible representation with highest weight hw. Alternatively, hw can also be a list of highest weights, in which case the representation is the direct sum of the irreducible representations with highest weights in the list. Hesselink ([Hes79]) defined a stratification of the nullcone relative to the action of G. Popov and Vinberg ([VP89]) have described this stratification in terms of characteristics, which are elements of a Cartan subalgebra of L. To each characteristic there corresponds a stratum. This function is an implementation of an algorithm due to Popov ([Pop03]), for computing the characteristics of the strata. It returns a list of two lists. The first list contains the characteristics. The second list contains the dimensions of the corresponding strata. If the highest weight hw defines the adjoint representation, then the characteristics of the strata are exactly the characteristics of the nilpotent orbits in L. This means the following: let h be a characteristic, then there are e,f in L such that the triple h,e,f satisfies the commutation relations of mathfraksl_2, and the elements e thus obtained are the representatives of the nilpotent G-orbits in L.

We remark that the characteristics depend on the choice of an invariant bilinear form. This form is unique if L is simple. If we give just two arguments, L, hw, then Killing form is chosen. It is possible to use a different form using the three argument variant of the function.

In the three argument variant L is a reductive Lie algebra and B is the restriction of a non-degenerate invariant bilinear form on the Cartan subalgebra of L. This bilinear form must be given with respect to a specific basis, which we now describe. Let K denote the derived subalgebra of L (which is semisimple). Let h be the list CanonicalGenerators( RootSystem( K ) )[3] (this is a basis of a Cartan subalgebra of K). Let c be the list BasisVectors( Basis( LieCentre(K) ) ). Then the basis we require is the concatenation of h and c. Again hw can be a highest weight, or a list of highest weights. These highest weights are lists of eigenvalues of the elements of the particular basis of a Cartan subalgebra of L described above.

    gap> L:= SimpleLieAlgebra("G",2,Rationals);;
    gap> CharacteristicsOfStrata( L, [0,1] );
    [ [ v.13+(2)*v.14, (2)*v.13+(3)*v.14, (2)*v.13+(4)*v.14, (6)*v.13+(10)*v.14 ],
      [ 6, 8, 10, 12 ] ]

In the next example we compute the strata of a representation of a reductive subalgebra of the Lie algebra of type E_6, obtained as the set of fixed points of an inner automorphism. We compute the strata of the θ-representation corresponding to the automorphism. For this we first need to work out the highest weights of the module. The bilinear form is the restriction of the Killing form to the subalgebra.

    gap> f:= FiniteOrderInnerAutomorphisms("E",6,3)[2];;
    gap> M:= Source(f);;
    gap> gr:= Grading(f);;
    gap> L:= Subalgebra(M,gr[1]);
    <Lie algebra over CF(3), with 28 generators>
    gap> K:= LieDerivedSubalgebra( L );
    <Lie algebra of dimension 27 over CF(3)>
    gap> V:= LeftAlgebraModuleByGenerators( K, function(x,v) return x*v; end, gr[2]);
    <left-module over <Lie algebra of dimension 27 over CF(3)>>
    gap> DisplayDynkinDiagram( K );
    A4:  1---4---3---2
    A1:  5
    gap> dV:= DirectSumDecomposition(V);
    [ <left-module over <Lie algebra of dimension 27 over CF(3)>>,
      <left-module over <Lie algebra of dimension 27 over CF(3)>> ]
    gap> DisplayHighestWeight( dV[1] );
    A4:  0---0---0---1
    A1:  0
    gap> DisplayHighestWeight( dV[2] );
    A4:  0---0---1---0
    A1:  1
    gap> t0:= Basis(LieCentre(L))[1];
    v.73+(4/5)*v.75+(3/5)*v.76+(2/5)*v.77+(1/5)*v.78
    gap> HighestWeightVector( dV[1] ); t0^last;
    v.7
    (6/5)*v.7
    gap> HighestWeightVector( dV[2] ); t0^last;
    v.13
    (-3/5)*v.13
    gap> hw:= [ [0,1,0,0,0,6/5], [0,0,1,0,1,-3/5] ];
    [ [ 0, 1, 0, 0, 0, 6/5 ], [ 0, 0, 1, 0, 1, -3/5 ] ]
    gap> bas:= Concatenation( CanonicalGenerators( RootSystem(K) )[3],
    > Basis(LieCentre(L)) );;
    gap> B:= List( bas, x -> [] );;
    gap> ad:= List( bas, x -> AdjointMatrix( Basis(M), x ) );;
    gap> for i in [1..Length(B)] do for j in [i..Length(B)] do
    > B[i][j]:= TraceMat( ad[i]*ad[j]); B[j][i]:= B[i][j];
    > od; od;
    gap> B;
    [ [ 48, 0, 0, -24, 0, 0 ], [ 0, 48, -24, 0, 0, 0 ], [ 0, -24, 48, -24, 0, 0 ],
    [ -24, 0, -24, 48, 0, 0 ], [ 0, 0, 0, 0, 48, 0 ], [ 0, 0, 0, 0, 0, 144/5 ] ]
    gap> CharacteristicsOfStrata( L, B, hw );
    [ [ v.74+v.75+v.76, v.73+v.75, (-2)*v.73,
          (2)*v.74+(2)*v.75+(3)*v.76+(2)*v.77+v.78, (-1)*v.73+(-1)*v.76+(-1)*v.77,
          v.73+v.74+(2)*v.75+v.76, (2)*v.73+(2)*v.74+(4)*v.75+(4)*v.76+(2)*v.77+(
            2)*v.78, (-2)*v.73+v.74, v.74+(4)*v.75+(2)*v.76+v.77+v.78,
          (-1)*v.73+v.74+v.75+v.76, (2)*v.73+(3)*v.74+(5)*v.75+(5)*v.76+(3)*v.77+(
            2)*v.78, v.73+(4)*v.75+v.76, v.75+(-1)*v.76+(-1)*v.77,
          v.73+v.74+(3)*v.75+(2)*v.76+v.78, (4)*v.73+(6)*v.74+(7)*v.75+(9)*v.76+(
            6)*v.77+(3)*v.78, (-3)*v.73+(-2)*v.75+(-2)*v.76+(-2)*v.77+(-1)*v.78,
          (4)*v.75+(2)*v.76, (2)*v.73+(6)*v.74+(8)*v.75+(8)*v.76+(4)*v.77+(2)*v.78
            , (2)*v.74+(4)*v.75+(2)*v.76+v.77+v.78,
          (2)*v.74+(4)*v.75+(2)*v.76+(-2)*v.77,
          v.73+v.74+(5)*v.75+(3)*v.76+v.77+v.78,
          v.73+(2)*v.74+(4)*v.75+(3)*v.76+v.77+v.78,
          (4)*v.73+(6)*v.74+(10)*v.75+(10)*v.76+(4)*v.77+(4)*v.78,
          (3)*v.73+(6)*v.74+(10)*v.75+(10)*v.76+(5)*v.77+(5)*v.78,
          (-1)*v.73+v.74+(3)*v.75+(-3)*v.77+(-1)*v.78,
          (6)*v.74+(10)*v.75+(8)*v.76+(2)*v.77+(2)*v.78 ],
      [ 8, 5, 16, 11, 12, 10, 13, 18, 18, 15, 15, 17, 13, 15, 16, 20, 20, 20, 19,
          21, 19, 17, 20, 22, 22, 24 ] ]

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 Bib Ind

generated by GAPDoc2HTML