///////////////////////////////////////////////////////////////////////////////
//                             Lisaac Compiler                               //
//                                                                           //
//                   LSIIT - ULP - CNRS - INRIA - FRANCE                     //
//                                                                           //
//   This program is free software: you can redistribute it and/or modify    //
//   it under the terms of the GNU General Public License as published by    //
//   the Free Software Foundation, either version 3 of the License, or       //
//   (at your option) any later version.                                     //
//                                                                           //
//   This program is distributed in the hope that it will be useful,         //
//   but WITHOUT ANY WARRANTY; without even the implied warranty of          //
//   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the           //
//   GNU General Public License for more details.                            //
//                                                                           //
//   You should have received a copy of the GNU General Public License       //
//   along with this program.  If not, see <http://www.gnu.org/licenses/>.   //
//                                                                           //
//                     http://isaacproject.u-strasbg.fr/                     //
///////////////////////////////////////////////////////////////////////////////
Section Header
  
  + name    := WRITE_LOCAL;

  - copyright   := "2003-2007 Benoit Sonntag";

  
  - author  := "Sonntag Benoit (bsonntag@loria.fr)";
  - comment := "Write local";
  
Section Inherit

  + parent_write:Expanded WRITE;
    
Section Public
    
  + local:LOCAL;
  
  - variable:VARIABLE <- local;
  
  //
  // Creation.
  //
  
  - create p:POSITION with val:EXPR in l:LOCAL :SELF <-
  ( + result:SELF;
    ? {p.code != 0};
    result := clone;
    result.make p with val in l;
    result
  );
  
  - make p:POSITION with val:EXPR in l:LOCAL <-
  (     
    position := p;
    local    := l;
    value    := val;
  );
    
  //
  // Execute.
  //
  
  - execute_access_unlink:INSTR <- NULL;
  
  - execute_access_link;

  - execute_argument:BOOLEAN <- 
  // BSBS: Cette methode foureuse ne doit plus etre necessaire (utilise execute normal)
  ( + new_val:INSTR;
    + read:READ;    
    + result:BOOLEAN;
    
    ? { variable != NULL };
    ? { value    != NULL };
    
    read ?= value;
    ((read != NULL) && {read.variable = variable}).if {
      remove;      
      result := TRUE;
    }.elseif {ensure_count = 0} then {
      //
      // Supprime affectation.
      //      
      new_val := value.execute_unlink;
      (new_val = NULL).if {
	result := TRUE;
      }.elseif {list_current.old_seq_or_and = seq_or_and} then {
	list_current.insert_before new_val;
	result := TRUE;
      } else {
	value ?= new_val;
      };
    } else {
      //
      // Execution normal.
      //            
      execute_access_link;
      value := value.execute_link;      
    };
    result
  );  
  
  //
  // Genere
  //
  
  - genere buffer:STRING <-
  ( 
    add_var_size local;
    (variable.ensure_count = -1).if {
      buffer.add_last '*';
    };
    buffer.append (variable.intern_name);     
    //
    ((value.static_type.raw = TYPE_NULL) && {variable.type.raw = type_block}).if {
      buffer.append ".__id=0";
    } else {
      buffer.add_last '=';    
      genere_value buffer;
    };
  );
    
  - genere_argument_result buffer:STRING <-
  ( 
    buffer.add_last '&';
    buffer.append (variable.intern_name);    
    local.set_ensure_count 1; // BSBS: Bidouille !
    add_var_size local;
  );
  






